@ECHO OFF
REM ====================================================================
REM MS-DOS batch to generate coordinates of the source and receiver points
REM for given configuration parameters, perform two-point ray tracing,
REM and convert unformatted output into a simple formatted file.
REM It runs programs 'srp', 'crt' and 'crtpts'.
REM ====================================================================
IF NOT "%1"=="" GOTO :RUN
  ECHO Purpose:
  ECHO     To generate coordinates of the source and receiver points for given
  ECHO     configuration parameters, perform two-point ray tracing, and convert
  ECHO     unformatted output into a simple formatted file.
  ECHO Usage:
  ECHO     srpcrt NAME NUM1
  ECHO     srpcrt NAME NUM1 NUM2
  ECHO Parameters:
  ECHO     NAME... prefix of data files (name of the job).
  ECHO     NUM1... integer configuration parameter.
  ECHO     NUM2... optional second configuration parameter.
  ECHO Executable programs required:
  ECHO     srp.exe, crt.exe, crtpts.exe
  ECHO Input files:
  ECHO     NAMEsrp.dat... input file for the 'srp' program to generate source
  ECHO             and receiver files for given configuration parameters.
  ECHO             The receiver file must be named NAME-rec.out.  Source and
  ECHO             receiver names will be prefixed with NUM1-.
  ECHO     NAMEcrt.dat... input file for the 'crt' program.
  ECHO Output files:
  ECHO     NAMENUM1NUM2.out... file containing travel times, slowness
  ECHO             vectors and amplitudes (in R.C.C.S.) at the receivers.
  ECHO     NAMEscr.out... collected screen output of programs 'srp.exe',
  ECHO             'crt.exe', and 'crtpts.exe' (written in an append mode).
  GOTO :END
:RUN
REM ....................................................................
REM Source and receiver points for given configuration parameters:
REM --------------------------------------------------------------
ECHO '%1srp.dat' '%2-' %2 %3 /|srp >>%1scr.out
IF ERRORLEVEL 1 PAUSE
REM
REM Ray tracing:
REM ------------
ECHO '%1crt.dat' /|crt >>%1scr.out
IF ERRORLEVEL 1 PAUSE
REM The above command should be modified if 'scropc.for' were included
REM within 'crt.for'.
REM
REM Results of ray tracing:
REM -----------------------
ECHO '%1rec.out' 3* '%1%2%3.out' 11 0 1 0 /|crtpts >>%1scr.out
REM
REM Screen output (output filename in red):
REM ---------------------------------------
ECHO %1%2%3.out
:END
REM ====================================================================