@ECHO OFF
REM ====================================================================
REM Sample MS-DOS batch file to compile and link single Fortran77 source
REM file using the Lahey compliler F77L3 and linker 386LINK.
REM Each user should modify this batch file for the use with his
REM favourite compiler.
REM ====================================================================
REM Help screen:
REM ~~~~~~~~~~~~
IF NOT '%1'=='' GOTO :START
ECHO Usage:
ECHO           F prog
ECHO.
ECHO prog...   name (without extension .FOR !) of the Fortran77 source file
ECHO           to be compiled and linked.  File prog.FOR is compiled and
ECHO           linked to generate prog.EXE and output list file prog.LST.
ECHO.
ECHO Note that some programs may require to set "remember local variables"
ECHO when compiled by the Lahey compliler F77L3.
GOTO :END
:START
REM ....................................................................
REM Compilation using F77L3: compiler messages are redirected to %1.LST:
REM ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
F77L3 %1 >%1.LST
IF NOT ERRORLEVEL 1 GOTO :CONTINUE
ECHO Error encountered: Refer to file %1.LST for the description!
GOTO :END
:CONTINUE
REM ....................................................................
REM Linking using 386LINK with the GRAPH3 CalComp graphic library:
REM ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
386LINK %1 -lib GRAPH3 -symbol
IF ERRORLEVEL 1 GOTO :END
DEL %1.OBJ
REM ....................................................................
:END
REM ====================================================================