C 
C Program TRSMSM to compute trace tr(SM1*SM2) of the product of two
C symmetric matrices SM1 and SM2
C
C Version: 5.50
C Date: 2001, May 12
C
C Coded by Petr Bulant and Ludek Klimes
C     Department of Geophysics, Charles University Prague,
C     Ke Karlovu 3, 121 16 Praha 2, Czech Republic,
C     E-mails: bulant@seis.karlov.mff.cuni.cz
C              klimes@seis.karlov.mff.cuni.cz
C
C.......................................................................
C                                                    
C Description of data files:
C
C Input data read from the standard input device (*):
C     The data are read by the list directed input (free format) and
C     consist of a single string 'SEP':
C     'SEP'...String in apostrophes containing the name of the input
C             SEP parameter or history file with the input data.
C     No default, 'SEP' must be specified and cannot be blank.
C
C                                                     
C Input data file 'SEP':
C     File 'SEP' has the form of the SEP
C     parameter file.  The parameters, which do not differ from their
C     defaults, need not be specified in file 'SEP'.
C Data specifying dimensions of the matrices:
C     M1='string'... Name of the file containing a single integer number
C             specifying the number of rows (and columns) of symmetric
C             matrices SM1 and SM2.
C             Default: M1=' ' means that the number is 1.
C Filenames of the files with the matrices:
C     SM1='string'... Name of the input file containing matrix SM1.
C             No default, SM1 must be specified and cannot be blank.
C     SM2='string'... Name of the input file containing matrix SM2.
C             No default, SM2 must be specified and cannot be blank.
C     TRACE='string'... Name of the output file containing a single
C             value, trace tr(SM1*SM2) of the product of two symmetric
C             matrices SM1 and SM2.
C             No default, TRACE must be specified and cannot be blank.
C     For general description of the files with matrices refer to file
C     forms.htm.
C Form of the files with matrices:
C     FORMM='string'... Form of the files with matrices. Allowed values
C             are FORMM='formatted' and FORMM='unformatted'. If the form
C             differs for input and for output files, FORMMR and FORMMW
C             should be used instead of FORMM.
C             Default: FORMM='formatted'
C     FORMMR='string'... Form of the files with matrices to be read.
C             Default: FORMMR=FORMM
C     FORMMW='string'... Form of the files with matrices to be written.
C             Default: FORMMW=FORMM
C
C-----------------------------------------------------------------------
C
C Subroutines and external functions required:
      EXTERNAL ERROR,RSEP1,RSEP3T,RMAT,WMAT
C     ERROR ... File error.for.
C     RSEP1,RSEP3T ... File sep.for.
C     RMAT,WMAT ... File forms.for.
C
C Common block /RAMC/:
      INCLUDE 'ram.inc'
C     ram.inc
C
      CHARACTER*80 FILSEP,FILE1,FILE2,FILE3
      INTEGER LU1,M1,NN,I1,I2,I
      PARAMETER (LU1=1)
      REAL TRACE
C
C-----------------------------------------------------------------------
C
C     Reading a name of the file with the input data:
      FILSEP=' '
      WRITE(*,'(A)') '+TRSMSM: Enter input filename: '
      READ(*,*) FILSEP
C
C     Reading all the data from the SEP file into the memory:
      IF (FILSEP.NE.' ') THEN
        CALL RSEP1(LU1,FILSEP)
      ELSE
C       TRSMSM-01
        CALL ERROR('TRSMSM-01: SEP file not given')
      ENDIF
C
C     Reading the dimension of the matrices:
      CALL RSEP3T('M1',FILE1,' ')
      IF (FILE1.EQ.' ') THEN
        M1=1
      ELSE
        OPEN(LU1,FILE=FILE1,STATUS='OLD')
        READ(LU1,*) M1
        CLOSE(LU1)
      ENDIF
      NN=M1*(M1+1)/2
C
      IF (2*NN.GT.MRAM) THEN
C       TRSMSM-02
        CALL ERROR('TRSMSM-02: Small dimension MRAM of array RAM')
      END IF
C
C     Reading the names of the files with the matrices:
      CALL RSEP3T('SM1',FILE1,' ')
      CALL RSEP3T('SM2',FILE2,' ')
      CALL RSEP3T('TRACE',FILE3,' ')
      IF (FILE1.EQ.' ') THEN
C       TRSMSM-03
        CALL ERROR('TRSMSM-03: Input file with matrix SM1 not given')
      ENDIF
      IF (FILE2.EQ.' ') THEN
C       TRSMSM-04
        CALL ERROR('TRSMSM-04: Input file with matrix SM2 not given')
      ENDIF
      IF (FILE3.EQ.' ') THEN
C       TRSMSM-05
        CALL ERROR('TRSMSM-05: Output filename TRACE not specified')
      ENDIF
C
C     Reading input matrices:
      CALL RMAT(LU1,FILE1,M1,0,RAM)
      CALL RMAT(LU1,FILE2,M1,0,RAM(NN+1))
C
      WRITE(*,'(A)') '+TRSMSM: Working...            '
C
C     Calculating the trace:
      TRACE=0.
      I=0
C     Loop over columns:
      DO 12, I2=1,M1
C       Loop over rows:
        DO 11, I1=1,I2-1
          I=I+1
          TRACE=TRACE+2.*RAM(I)*RAM(NN+I)
  11    CONTINUE
        I=I+1
        TRACE=TRACE+RAM(I)*RAM(NN+I)
  12  CONTINUE
C
C     Writing output file TRACE:
      RAM(1)=TRACE
      IF (FILE3.NE.' ') THEN
        CALL WMAT(LU1,FILE3,1,1,RAM)
      ENDIF
      WRITE(*,'(A)') '+TRSMSM: Done.                 '
C
      STOP
      END
C
C=======================================================================
C
      INCLUDE 'error.for'
C     error.for
      INCLUDE 'sep.for'
C     sep.for
      INCLUDE 'forms.for'
C     forms.for
      INCLUDE 'length.for'
C     length.for
C
C=======================================================================
C